Skip to content

opsi.orgheader image

opsi.org
 
Views
Actions
WinstScripts >>

seamonkey

Document Actions
last edited 11 months ago by sehlers
Two Scripts: install (mozilla.ins) and uninstall (delmozilla.ins)

Quaalified for opsi 3.4
---------------------------------------------------------------------

mozilla.ins

---------------------------------------------------------------------
; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib
; and published under the Terms of the General Public License.

[Initial]
; Message at install time:
Message=installing mozilla / seamonkey ......
LogLevel=2
;  Log Errors in Logfile but don't abort:
ExitOnError=false
; Show syntax errors in the script:
ScriptErrorMessages=on
; Dont trace step by step through the script:
TraceMode=off
; let started programs run in front of the winst window
StayOnTop=false



[Aktionen]
; some variables for the sub sections
DefVar $SYSTEMROOT$
DefVar $SYSTEMDRIVE$
DefVar $ScriptPath$
DefVar $ProgramFilesDir$
DefVar $HOST$
DefVar $PCName$
Set $SYSTEMDRIVE$ = "%SYSTEMDRIVE%"
Set $SYSTEMROOT$ = "%SYSTEMROOT%"
set $ScriptPath$="%ScriptPath%"
set $ProgramFilesDir$="%ProgramFilesDir%"
set $Host$="%Host%"
set $PCName$="%PCName%"
; temp is always useful
DefVar $TEMP$
Set $TEMP$= EnvVar("TEMP")
;Variables for version of the operating system (OS)-Test
DefVar $OS$
DefVar $MinorOS$

set $OS$ = GetOS
set $MinorOS$ = GetNTVersion

; Check for outlookonfig
DefVar $Outlookkonfig$
Set $Outlookkonfig$ = "False"

if fileExists ("c:\Programme\outlookkonfig\configure_outlook.ins")
   Set $Outlookkonfig$ = "True"
endif

LogLevel=-2
;Registry_del_autologin
LogLevel=2
if ( $OS$ = "Windows_NT" OR $OS$ = "Windows_95" )
  if not(HasMinimumSpace ("%SYSTEMDRIVE%", "50 MB"))
   LogError "Nicht genügend Platz auf C: 50 MB auf C: für Mozilla erforderlich."
 else
;  show product picture
   ShowBitmap /3 "%scriptpath%\seamonkey.bmp" "Seamonkey"


   DefVar $MozNewInstallDir$
   set $MozNewInstallDir$ = "%ProgramFilesDir%\mozilla.org\Seamonkey"
;get path to currently installed mozilla
   DefVar $MozInstallDir$
   DefVar $MozVersion$
   DefVar $MozInstallPathRegKey$
   set $MozVersion$ = GetRegistryStringValue ("[HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla] CurrentVersion")
   set $MozInstallPathRegKey$ = "[HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla\"+$MozVersion$+"\Main]"
   set $MozInstallDir$ = GetRegistryStringValue ($MozInstallPathRegKey$+" Install Directory")

; kill a running mozilla
  killtask "mozilla.exe"
  killtask "seamonkey.exe"
; if mozilla uninstall program exist then start it
   if FileExists("%SYSTEMROOT%\MozillaUninstall.exe")
    ;WinBatch_start_MozillaUninstall
   endif
; delete registry entry to the current installed version
   Registry_delete_current_mozversion
   LinkFolder_delete
; delete files of current version 
   Files_copy_deinstall
   if FileExists("C:\programme\netscape")
    Files_copy_deinstall_netscape
   endif 

   set $MozVersion$ = GetRegistryStringValue ("[HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey] CurrentVersion")
   set $MozInstallPathRegKey$ = "[HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey\"+$MozVersion$+"\Main]"
   set $MozInstallDir$ = GetRegistryStringValue ($MozInstallPathRegKey$+" Install Directory")
; if mozilla uninstall program exist then start it
   if FileExists("%SYSTEMROOT%\SeamonkeyUninstall.exe")
     WinBatch_start_SeamonkeyUninstall
   endif
   if FileExists($MozInstallDir$+"\uninstall\SeaMonkeyUninstall.exe")
     WinBatch_start_SeamonkeyUninstall_2
   endif
    if FileExists("C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.1_2006013000\uninstall\GREUninstall.exe")
     ; don't start it: it has a bug
     ; WinBatch_start_GeckoUninstall_101
    endif
    if FileExists("C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.6_2006072904\uninstall\GREUninstall.exe")
     ; don't start it: it has a bug
     ; WinBatch_start_GeckoUninstall_104
    endif
		     
; delete registry entry to the current installed version
   Registry_delete_current_seaversion
   ; Registry_delete_current_user /AllNtUserdats
   ; works not wit delete command
   Files_delete_temp /AllNTUserProfiles
   LinkFolder_delete
; delete files of current version 
   Files_copy_deinstall
; delete files of current version 
   Files_copy_deinstall_gre
; check for depotshare   
  if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
  endif   
; start setup program
   Winbatch_Mozilla
; kill a running mozilla
   killtask "mozilla.exe"
   killtask "seamonkey.exe"

; Repair Current Version Registry Key
; If it missed, Java Applets don't work
; see http://plugindoc.mozdev.org/faqs/java.html
  Registry_set_current_mozversion

; set seamonkey as standard mail and browser
   if ($MinorOS$ = "NT4")
    if not (FileExists("%AppDataDir%\mozilla\registry.dat"))
     Winbatch_start_seamonkey_with_create_profile
    endif
   endif
; check for depotshare   
  if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
  endif   
   Winbatch_autoit_defaultbrowser /LetThemGo
   Winbatch_mozilla_startbrowser
   if ($MinorOS$ = "NT4")
    DosInAnIcon_wait
   endif
   killtask "AutoIt3.exe"
   killtask "seamonkey.exe"

; don't start mozilla at login
   LinkFolder_Autostart_Mozilla
; check for depotshare   
  if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
  endif   
; copy some standard plugins e.g. fentun.exe
   Files_copy_plugin

;  add seamonkey to port 25 Filter whitelist in mcafee 8.0i virscan
   DefVar $WhiteList$
   set $WhiteList$ = GetRegistryStringValue ("[HKEY_LOCAL_MACHINE\SOFTWARE\Network Associates\TVD\Shared Components\On Access Scanner\BehaviourBlocking] PortBlockWhiteList_0")
   if not ($WhiteList$ = "")
    Registry_mcafee_dont_filter_seamonkey
   endif

  if IniVar ("open_eml") = "on"
   Registry_open_eml_files
  endif

  if ( IniVar("enigmail") = "on" ) AND ( NOT ($Outlookkonfig$ = "True" ) )
;  check for depotshare   
   if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
   endif  
;  install enigmail xpi
   Winbatch_autoit_install_xpi /LetThemGo
;  check for depotshare   
   if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
   endif   
   Winbatch_mozilla_enigmail_de
   ;Winbatch_mozilla_enigmail1
   if ($MinorOS$ = "NT4")
    DosInAnIcon_wait
   endif
   killtask "AutoIt3.exe"
;  install enigmail language xpi
;  check for depotshare   
   if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
   endif
   Winbatch_autoit_install_xpi /LetThemGo
;  check for depotshare   
   if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
   endif   
   Winbatch_mozilla_enigmail2
   if ($MinorOS$ = "NT4")
    DosInAnIcon_wait
   endif
   killtask "AutoIt3.exe"
;  restart for correct language pack integration
;  check for depotshare   
   if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
   endif
   Winbatch_autoit_restart_german /LetThemGo
;  check for depotshare   
   if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
   endif   
   Winbatch_mozilla_startbrowser
   if ($MinorOS$ = "NT4")
    DosInAnIcon_wait
   endif
   killtask "AutoIt3.exe"
  endif

; check for depotshare   
  if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
  endif  
  if ( NOT ($Outlookkonfig$ = "True" ) )
    Winbatch_autoit_defaultmailclient /LetThemGo
; check for depotshare   
    if not (FileExists("%SCRIPTPATH%"))
     DosInAnIcon_TryToReconnect
    endif  
    Winbatch_mozilla_startmail
  endif
  if ($MinorOS$ = "NT4")
   DosInAnIcon_wait
  endif
  killtask "AutoIt3.exe"
  killtask "seamonkey.exe"
  if FileExists("%AppDataDir%\Mozilla\registry.dat") 
   Files_Remove_Default_User_profile
  endif
  

; custom specific stuff
  if FileExists("%ScriptPath%\ur_ins_dir\custom.ins")
   sub "%ScriptPath%\ur_ins_dir\custom.ins"
  endif
  

 endif
endif

[Files_copy_deinstall]
Delete -sf "$MozInstallDir$"

[Files_copy_deinstall_netscape]
Delete -sf "C:\Programme\Netscape"

[Files_copy_deinstall_gre]
Delete -sf "C:\Programme\Gemeinsame Dateien\mozilla.org\GRE"

[Files_copy_plugin]
copy -s %scriptpath%\plugins\*.*  $MozNewInstallDir$\plugins

[Winbatch_Mozilla]
%ScriptPath%\seamonkey-1.1.17.de-AT.win32.installer.exe -ma

[WinBatch_start_MozillaUninstall]
%SYSTEMROOT%\MozillaUninstall.exe /ma

[WinBatch_start_SeamonkeyUninstall]
%SYSTEMROOT%\SeamonkeyUninstall.exe /ma

[WinBatch_start_SeamonkeyUninstall_2]
$MozInstallDir$\uninstall\SeaMonkeyUninstall.exe /ma

[WinBatch_start_GeckoUninstall_101]
"C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.1_2006013000\uninstall\GREUninstall.exe" -ma

[WinBatch_start_GeckoUninstall_104]
""C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.6_2006072904\uninstall\GREUninstall.exe" -ma

[LinkFolder_delete]
set_basefolder common_programs
delete_subfolder "Mozilla"
delete_subfolder "Seamonkey"

[LinkFolder_mozilla]
set_basefolder common_programs
set_subfolder "Mozilla"

[Files_copy_icon]
copy -v %scriptpath%\icon\mozilla.ico $MozNewInstallDir$

[LinkFolder_Autostart_Mozilla]
set_basefolder common_startup
set_subfolder ""
delete_element "Mozilla"
delete_element "Seamonkey"

[Registry_delete_current_mozversion]
OpenKey [HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla]
set "CurrentVersion" = ""

[Registry_set_current_mozversion]
OpenKey [HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla]
set "CurrentVersion" = "1.1.17 (de)"

[Registry_delete_current_seaversion]
OpenKey [HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey]
set "CurrentVersion" = ""
;deleteKey [HKEY_LOCAL_MACHINE\SOFTWARE\mozilla.org\GRE]

; [Registry_delete_current_user]
; DeleteKey [Software\mozilla.org]
; DeleteKey [Software\Mozilla]

[Registry_open_eml_files]
openkey [HKEY_CLASSES_ROOT\.eml]
set ""="MozillaEML"
set "Content Type"="message/rfc822"
openkey [HKEY_CLASSES_ROOT\MozillaEML]
set ""="Mail-Datei"
openkey [HKEY_CLASSES_ROOT\MozillaEML\DefaultIcon]
set ""="$MozNewInstallDir$\\COMPONENTS\\msgbase.dll,0"
openkey [HKEY_CLASSES_ROOT\MozillaEML\shell\open\command]
set ""="$MozNewInstallDir$\\Seamonkey.exe -url %1"

[Registry_seamonkey_is_standard]
openkey [Software\Clients\Mail]
set ""="Seamonkey"
openkey [Software\Classes]
set "http\shell\open\ddeexec\application"="Seamonkey"

[Winbatch_autoit_install_xpi]
%SCRIPTPATH%\AutoIt3.exe %ScriptPath%\install_xpi.au3

[Winbatch_mozilla_enigmail_de]
"$MozNewInstallDir$\seamonkey.exe" %ScriptPath%\extensions\Enigmail_0.95.6_tb_sm_de.xpi

[Winbatch_mozilla_enigmail1]
"$MozNewInstallDir$\seamonkey.exe" %ScriptPath%\extensions\enigmail-0.95.6-tb+sm.xpi

[Winbatch_mozilla_enigmail2]
"$MozNewInstallDir$\seamonkey.exe" %ScriptPath%\extensions\enigmail-de-0.95.xpi

[Winbatch_autoit_defaultbrowser]
%SCRIPTPATH%\AutoIt3.exe %ScriptPath%\defaultbrowser.au3

[Winbatch_mozilla_startbrowser]
"$MozNewInstallDir$\seamonkey.exe" -contentLocale de-AT -UILocale AT %ScriptPath%\mozilla_wait_config.html

[Winbatch_start_seamonkey_with_create_profile]
"$MozNewInstallDir$\seamonkey.exe" -createProfile

[Winbatch_autoit_restart_german]
%SCRIPTPATH%\AutoIt3.exe %ScriptPath%\close_mozilla.au3
            
[Winbatch_autoit_defaultmailclient]
%SCRIPTPATH%\AutoIt3.exe %ScriptPath%\defaultmail.au3

[Winbatch_mozilla_startmail]
"$MozNewInstallDir$\seamonkey.exe" -mail

[Registry_mcafee_dont_filter_seamonkey]
openkey [HKEY_LOCAL_MACHINE\SOFTWARE\Network Associates\TVD\Shared Components\On Access Scanner\BehaviourBlocking]
supp "PortBlockWhiteList_0" , "seamonkey.exe"

[Files_Remove_Default_User_profile]
delete -fs "%AppdataDir%\Mozilla"

[DosInAnIcon_wait]
sleep 20

[Files_delete_temp]
delete -sfd21 "%UserProfileDir%\Lokale Einstellungen\Temp\*.*"

[DosInAnIcon_TryToReconnect]
net use
set TIMEOUT=
:TRY
if exist "%SCRIPTPATH%\." goto READY
%ScriptDrive%
set TIMEOUT=%TIMEOUT%1
if %TIMEOUT% == 1111111111111111 goto READY
sleep 1
net use
goto TRY
:READY


--------------------------------------------------------------------

delmozilla.ins

--------------------------------------------------------------------
; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib
; and published under the Terms of the General Public License.

[Initial]
; Message at install time:
Message=deinstalling mozilla / seamonkey ......
LogLevel=2
;  Log Errors in Logfile but don't abort:
ExitOnError=false
; Show syntax errors in the script:
ScriptErrorMessages=on
; Dont trace step by step through the script:
TraceMode=off
; let started programs run in front of the winst window
StayOnTop=false



[Aktionen]
; some variables for the sub sections
DefVar $SYSTEMROOT$
DefVar $SYSTEMDRIVE$
DefVar $ScriptPath$
DefVar $ProgramFilesDir$
DefVar $HOST$
DefVar $PCName$
Set $SYSTEMDRIVE$ = "%SYSTEMDRIVE%"
Set $SYSTEMROOT$ = "%SYSTEMROOT%"
set $ScriptPath$="%ScriptPath%"
set $ProgramFilesDir$="%ProgramFilesDir%"
set $Host$="%Host%"
set $PCName$="%PCName%"
; temp is always useful
DefVar $TEMP$
Set $TEMP$= EnvVar("TEMP")
;Variables for version of the operating system (OS)-Test
DefVar $OS$
DefVar $MinorOS$

set $OS$ = GetOS
set $MinorOS$ = GetNTVersion
if ( $OS$ = "Windows_NT" OR $OS$ = "Windows_95" )
;  show product picture
   ShowBitmap /3 "%scriptpath%\seamonkey.bmp" "Seamonkey"


   DefVar $MozNewInstallDir$
   set $MozNewInstallDir$ = "%ProgramFilesDir%\mozilla.org\Seamonkey"
;get path to currently installed mozilla
   DefVar $MozInstallDir$
   DefVar $MozVersion$
   DefVar $MozInstallPathRegKey$
   set $MozVersion$ = GetRegistryStringValue ("[HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla] CurrentVersion")
   set $MozInstallPathRegKey$ = "[HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla\"+$MozVersion$+"\Main]"
   set $MozInstallDir$ = GetRegistryStringValue ($MozInstallPathRegKey$+" Install Directory")

; kill a running mozilla
  killtask "mozilla.exe"
  killtask "seamonkey.exe"
; if mozilla uninstall program exist then start it
   if FileExists("%SYSTEMROOT%\MozillaUninstall.exe")
    WinBatch_start_MozillaUninstall
   endif
; delete registry entry to the current installed version
   Registry_delete_current_mozversion
   LinkFolder_delete
; delete files of current version 
   Files_copy_deinstall

   set $MozVersion$ = GetRegistryStringValue ("[HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey] CurrentVersion")
   set $MozInstallPathRegKey$ = "[HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey\"+$MozVersion$+"\Main]"
   set $MozInstallDir$ = GetRegistryStringValue ($MozInstallPathRegKey$+" Install Directory")
;  if mozilla uninstall program exist then start it
   if FileExists("%SYSTEMROOT%\SeamonkeyUninstall.exe")
     WinBatch_start_SeamonkeyUninstall
   endif
   if FileExists($MozInstallDir$+"\uninstall\SeaMonkeyUninstall.exe")
     WinBatch_start_SeamonkeyUninstall_2
   endif
   if FileExists("C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.1_2006013000\uninstall\GREUninstall.exe")
     ; don't start it: it has a bug
     ; WinBatch_start_GeckoUninstall_101
    endif
    if FileExists("C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.6_2006072904\uninstall\GREUninstall.exe")
     ; don't start it: it has a bug
     ; WinBatch_start_GeckoUninstall_104
    endif
		     
; delete registry entry to the current installed version
   Registry_delete_current_seaversion
   LinkFolder_delete
; delete files of current version 
   Files_copy_deinstall
; delete files of current version 
   Files_copy_deinstall_gre
endif

[Files_copy_deinstall]
Delete -sf $MozInstallDir$

[Files_copy_deinstall_gre]
Delete -sf "C:\Programme\Gemeinsame Dateien\mozilla.org\GRE"

[WinBatch_start_MozillaUninstall]
%SYSTEMROOT%\MozillaUninstall.exe /ma

[WinBatch_start_SeamonkeyUninstall]
%SYSTEMROOT%\SeamonkeyUninstall.exe /ma

[WinBatch_start_SeamonkeyUninstall_2]
$MozInstallDir$\uninstall\SeaMonkeyUninstall.exe /ma

[WinBatch_start_GeckoUninstall_101]
"C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.1_2006013000\uninstall\GREUninstall.exe" -ma

[WinBatch_start_GeckoUninstall_104]
""C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.6_2006072904\uninstall\GREUninstall.exe" -ma

[LinkFolder_delete]
set_basefolder common_programs
delete_subfolder "Mozilla"
delete_subfolder "Seamonkey"

[LinkFolder_Autostart_Mozilla]
set_basefolder common_startup
set_subfolder ""
delete_element "Mozilla"
delete_element "Seamonkey"

[Registry_delete_current_mozversion]
OpenKey [HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla]
set "CurrentVersion" = ""

[Registry_delete_current_seaversion]
OpenKey [HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey]
set "CurrentVersion" = ""
deleteKey [HKEY_LOCAL_MACHINE\SOFTWARE\mozilla.org\GRE]

[Files_Remove_Default_User_profile]
delete -fs "%AppdataDir%\Mozilla"; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib
; and published under the Terms of the General Public License.

[Initial]
; Message at install time:
Message=deinstalling mozilla / seamonkey ......
LogLevel=2
;  Log Errors in Logfile but don't abort:
ExitOnError=false
; Show syntax errors in the script:
ScriptErrorMessages=on
; Dont trace step by step through the script:
TraceMode=off
; let started programs run in front of the winst window
StayOnTop=false



[Aktionen]
; some variables for the sub sections
DefVar $SYSTEMROOT$
DefVar $SYSTEMDRIVE$
DefVar $ScriptPath$
DefVar $ProgramFilesDir$
DefVar $HOST$
DefVar $PCName$
Set $SYSTEMDRIVE$ = "%SYSTEMDRIVE%"
Set $SYSTEMROOT$ = "%SYSTEMROOT%"
set $ScriptPath$="%ScriptPath%"
set $ProgramFilesDir$="%ProgramFilesDir%"
set $Host$="%Host%"
set $PCName$="%PCName%"
; temp is always useful
DefVar $TEMP$
Set $TEMP$= EnvVar("TEMP")
;Variables for version of the operating system (OS)-Test
DefVar $OS$
DefVar $MinorOS$

set $OS$ = GetOS
set $MinorOS$ = GetNTVersion
if ( $OS$ = "Windows_NT" OR $OS$ = "Windows_95" )
;  show product picture
   ShowBitmap /3 "%scriptpath%\seamonkey.bmp" "Seamonkey"


   DefVar $MozNewInstallDir$
   set $MozNewInstallDir$ = "%ProgramFilesDir%\mozilla.org\Seamonkey"
;get path to currently installed mozilla
   DefVar $MozInstallDir$
   DefVar $MozVersion$
   DefVar $MozInstallPathRegKey$
   set $MozVersion$ = GetRegistryStringValue ("[HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla] CurrentVersion")
   set $MozInstallPathRegKey$ = "[HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla\"+$MozVersion$+"\Main]"
   set $MozInstallDir$ = GetRegistryStringValue ($MozInstallPathRegKey$+" Install Directory")

; kill a running mozilla
  killtask "mozilla.exe"
  killtask "seamonkey.exe"
; if mozilla uninstall program exist then start it
   if FileExists("%SYSTEMROOT%\MozillaUninstall.exe")
    WinBatch_start_MozillaUninstall
   endif
; delete registry entry to the current installed version
   Registry_delete_current_mozversion
   LinkFolder_delete
; delete files of current version 
   Files_copy_deinstall

   set $MozVersion$ = GetRegistryStringValue ("[HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey] CurrentVersion")
   set $MozInstallPathRegKey$ = "[HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey\"+$MozVersion$+"\Main]"
   set $MozInstallDir$ = GetRegistryStringValue ($MozInstallPathRegKey$+" Install Directory")
;  if mozilla uninstall program exist then start it
   if FileExists("%SYSTEMROOT%\SeamonkeyUninstall.exe")
     WinBatch_start_SeamonkeyUninstall
   endif
   if FileExists($MozInstallDir$+"\uninstall\SeaMonkeyUninstall.exe")
     WinBatch_start_SeamonkeyUninstall_2
   endif
   if FileExists("C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.1_2006013000\uninstall\GREUninstall.exe")
     ; don't start it: it has a bug
     ; WinBatch_start_GeckoUninstall_101
    endif
    if FileExists("C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.6_2006072904\uninstall\GREUninstall.exe")
     ; don't start it: it has a bug
     ; WinBatch_start_GeckoUninstall_104
    endif
		     
; delete registry entry to the current installed version
   Registry_delete_current_seaversion
   LinkFolder_delete
; delete files of current version 
   Files_copy_deinstall
; delete files of current version 
   Files_copy_deinstall_gre
endif

[Files_copy_deinstall]
Delete -sf $MozInstallDir$

[Files_copy_deinstall_gre]
Delete -sf "C:\Programme\Gemeinsame Dateien\mozilla.org\GRE"

[WinBatch_start_MozillaUninstall]
%SYSTEMROOT%\MozillaUninstall.exe /ma

[WinBatch_start_SeamonkeyUninstall]
%SYSTEMROOT%\SeamonkeyUninstall.exe /ma

[WinBatch_start_SeamonkeyUninstall_2]
$MozInstallDir$\uninstall\SeaMonkeyUninstall.exe /ma

[WinBatch_start_GeckoUninstall_101]
"C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.1_2006013000\uninstall\GREUninstall.exe" -ma

[WinBatch_start_GeckoUninstall_104]
""C:\Programme\Gemeinsame Dateien\mozilla.org\GRE\1.8.0.6_2006072904\uninstall\GREUninstall.exe" -ma

[LinkFolder_delete]
set_basefolder common_programs
delete_subfolder "Mozilla"
delete_subfolder "Seamonkey"

[LinkFolder_Autostart_Mozilla]
set_basefolder common_startup
set_subfolder ""
delete_element "Mozilla"
delete_element "Seamonkey"

[Registry_delete_current_mozversion]
OpenKey [HKEY_LOCAL_MACHINE\Software\mozilla.org\Mozilla]
set "CurrentVersion" = ""

[Registry_delete_current_seaversion]
OpenKey [HKEY_LOCAL_MACHINE\Software\mozilla.org\Seamonkey]
set "CurrentVersion" = ""
deleteKey [HKEY_LOCAL_MACHINE\SOFTWARE\mozilla.org\GRE]

[Files_Remove_Default_User_profile]
delete -fs "%AppdataDir%\Mozilla"